9. تمرين - دوال النص
المتطلبات الأساسية
ينبغي قراءة دوال أكسل 2016 إلى غاية الدرس دالات النص لإنجاز هذا التمرين.
السؤال
لنعتبر جدول البيانات التالي حيث تم إدراج أسماء في العمود A. الهدف من التمرين هو استخراج الإسم الأول لعرضه في العمود B. و استخراج إسم الأب لعرضه في العمود C.
نعتبر أن الإسم الأول و إسم الأب مفصولان بحرف "مساحة". كما لا يوجد إسم أول مركب يحتوي على حرف "مساحة".
اكتب الصيغتين المناسبتين في الخليتين B2 و C2.
ملاحظة. يمكن حل هذه المسألة باستخدام معالج تحويل النص إلى أعمدة لبرنامج Excel. يمكنك إطلاق هذا المعالج باستخدام الأمر النص إلى أعمدة في علامة التبويب بيانات للشريط. ومع ذلك ، أطلب منك حلها بالصيغ ؛ إنه مثال جيد جدًا على استخدام دوال النص من Excel.
إشارات لحل التمرين - دوال النص
1 - الصيغة في الخلية B2 لاستخراج الأسماء الأولى؟
الحل:
=MID(A2, 1, FIND(" ", A2)-1)
الشروح:
الاسم الأول جزء من النص الموجود في الخلية A2 ، لذلك استخدم الدالة MID.
أعطي في الوسيطة الأولى النص الذي أريد استخلاص جزء منه ، وبالتالي عنوان الخلية A2.
في الوسيطة الثانية ، 1 ، لكي نستخلص الاسم الأول من بداية النص في الخلية A2. هكذا:
=MID(A2, 1, ----------)
في الوسيطة الثالثة ، هو عدد أحرف الاسم الأول. في الصف 2 ، عدد أحرف الاسم الأول هو 10. ولكن ، لا ننسى أننا سنقوم بملء خلايا العمود B بتقنية التعبئة التلقائية ، ويتنوع عدد الأحرف في الاسم الأول من صف إلى آخر.
الحل هو الإشارة إلى موضع الحرف "مساحة" في سلسلة أحرف الخلية A2. إنها الدالة FIND التي تُرجع موضع حرف في نص. لذلك ، صيغة البحث عن موضع الحرف "مساحة" هي:
FIND(" ", A2)
بالنسبة لعدد الأحرف في الاسم الأول ، يجب أن أطرح 1 لعدم احتساب الحرف "مساحة":
FIND(" ", A2)-1
الصيغة الإجمالية في B2 هي:
=MID(A2, 1, FIND(" ", A2)-1)
ملاحظة. هنا لدينا مثال على طلب متداخل لدالات ، حيث يتم إعطاء نتيجة الدالة FIND كوسيطة للدالة MID. يمكننا تجنب هذا الطلب المتداخل كما يلي:
في الخلية D2 على سبيل المثال ، اكتب الصيغة:
=FIND(" ", A2)
إذا كنت تريد إظهار الهدف من العمود D ، فأدخل في الخلية D1 العبارة : موضع الحرف "مساحة".
يمكنك إذن كتابة الصيغة في الخلية B2:
=MID(A2, 1, D2-1)
2 - الصيغة في الخلية C2 لاستخراج الأسماء الثانية؟
الحل:
=MID(A2, FIND(" ", A2) + 1, LEN(A2) - FIND(" ", A2))
الشروح:
ما زلنا نستخدم الدالة MID لاستخراج جزء من سلسلة نصية.
في الوسيطة الثانية:
FIND(" ", A2) + 1
لقد أضفنا 1 على موضع الحرف "مساحة" للحصول على الموضع في النص الذي يلي موضع الحرف "مساحة" ، حيث نجد في الخلية A2 الإسم الثاني مكتوب بعد الحرف "مساحة".
فيما يتعلق بالوسيطة الثالثة ، يجب أن تكون عدد الأحرف في الاسم الثاني. و لكن ، بالنسبة للدالة MID ، عندما نريد استخراج الأحرف الموجودة في نهاية السلسلة النصية ، من الممكن إعطاء عدد أكبر في الوسيطة الثالثة وسيقوم Excel بإرجاع الأحرف المتبقية ، أي حتى نهاية السلسلة A2. أعطي على سبيل المثال 100 ، لأنه لا يوجد اسم يحتوي على أكثر من 100 حرف.
لتكون الصيغة في الخلية C2:
=MID(A2, FIND(" ", A2) + 1, 100)
إلا أنه ، من الممكن حساب عدد أحرف الاسم الثاني بالضبط. لهذا ، من الضروري استخدام الدالة LEN التي تُرجع عدد أحرف سلسلة نصية. لإيجاد عدد حروف الاسم الثاني ، قم بطرح عدد الأحرف بدءا من الحرف "مساحة" من العدد الإجمالي لأحرف النص في A2 :
LEN(A2) - FIND(" ", A2)
وبالتالي الصيغة في C2:
=MID(A2, FIND(" ", A2) + 1, LEN(A2) - FIND(" ", A2))
ملاحظة. لتجنب الطلب المتداخل للدالات ، يمكنك هنا أيضًا استخدام صيغ في خلايا وسيطة. في حالة المستخرج أدناه ، تكون الصيغة في D2 هي:
=FIND(" ", A2)
الصيغة في E2 هي:
=LEN(A2) - FIND(" ", A2)
الصيغة في C2 هي:
=MID(A2, D2 + 1, E2)
تعليقات القارئ
